SteveHopwood » Mon Jan 28, 2019 8:54 pm wrote:V 2q is in post 1, with the fix for the pending orders stuff that c1borg posted in the 'Confused' thread - http://www.stevehopwoodforex.com/phpBB3 ... 29#p165929

I could not believe the bollocks I had coded when I looked at it in response to c1borg's thread.

I do have an excuse. Any of us who have developed as self-taught coders will find the same thingy here. How to code something does not tend to be difficult - CrapQl4 is a very simple language. It is the what to code that can be a bit of a bugger to work out.

It is quite some time since I last worked out the what to code quite as badly as this little lot.

There was no need to update the user guide. The new inputs should be self-explanatory.

DIYers, do this:
Do a search for: "enum PendingTradeTypes". It is only a few lines down. Copy this over the top of the existing code block:

Code: Select all

enum PendingTradeTypes
{
   Stop_order_only,
   Limit_order_only,
   Stop_and_Limit_orders,
};

Then do a search for: "extern PendingTradeTypes TypeOfPendingTrade=". I cannot remember what the original default was, so change it to:
extern PendingTradeTypes TypeOfPendingTrade=Stop_order_only;

Then search for, "void CanWeSendTrades(string symbol, int pairIndex, int signal)" to navigate to the relevant function. Easiest is to simply copy this over the top of the existing function:

Code: Select all

void CanWeSendTrades(string symbol, int pairIndex, int signal)
{

   bool result = false;
   
   if (!hedged)
      if (!StopTrading)
      {
         if (TimeCurrent() >= TimeToStartTrading[pairIndex])
         {
            if (OpenTrades < MaxTradesAllowed)
            {
               if (BuySignal || SellSignal)
               {
                 if (BuySignal)
                 {
                     //Immediate market trade
                     if (SendImmediateMarketTrade)
                        result = LookForTradingOpportunities(symbol, pairIndex, OP_BUY);
                     
                     //Pending orders
                     if (SendPendingTrades)
                     {
                        if (TypeOfPendingTrade == Stop_order_only)
                           result = LookForTradingOpportunities(symbol, pairIndex, OP_BUYSTOP);
                           
                        if (TypeOfPendingTrade == Limit_order_only)
                           result = LookForTradingOpportunities(symbol, pairIndex, OP_BUYLIMIT);
                           
                        if (TypeOfPendingTrade == Stop_and_Limit_orders)
                        {
                           result = LookForTradingOpportunities(symbol, pairIndex, OP_BUYSTOP);
                           
                           Sleep(5000);//Give the platform time to catch up
                           
                           result = LookForTradingOpportunities(symbol, pairIndex, OP_BUYLIMIT);
                        }//if (TypeOfPendingTrade == Stop_and_Limit_orders)
                        
                           
                     }//if (SendPendingTrades)
                     
                     
                     if (UseGridTrading && (SendImmediateMarketTrade || SendPendingTrades))
                        if (result)
                        {
                           if (TypeOfGrid == Stop || TypeOfGrid == Both)
                           {
                              SendBuyGrid(symbol, OP_BUYSTOP, ask, Lot, GridSize );
                           }//if (TypeOfGrid == OP_BUYSTOP || TypeOfGrid == Both)
                           
                           if (TypeOfGrid == Limit || TypeOfGrid == Both)
                           {
                              SendBuyGrid(symbol, OP_BUYLIMIT, ask, Lot, GridSize );
                           }//if (TypeOfGrid == OP_BUYSTOP || TypeOfGrid == Both)
                           
                        }//if (result)
                     
                  }//if (BuySignal)

                     
                  if (SellSignal)
                  {
                     
                     //Immediate market trade
                     if (SendImmediateMarketTrade)   
                        result = LookForTradingOpportunities(symbol, pairIndex, OP_SELL);
                     
                     //Pending orders
                     if (SendPendingTrades)
                     {
                        if (TypeOfPendingTrade == Stop_order_only)
                           result = LookForTradingOpportunities(symbol, pairIndex, OP_SELLSTOP);
                           
                        if (TypeOfPendingTrade == Limit_order_only)
                           result = LookForTradingOpportunities(symbol, pairIndex, OP_SELLLIMIT);
                           
                        if (TypeOfPendingTrade == Stop_and_Limit_orders)
                        {
                           result = LookForTradingOpportunities(symbol, pairIndex, OP_SELLSTOP);
                           
                           Sleep(5000);//Give the platform time to catch up
                           
                           result = LookForTradingOpportunities(symbol, pairIndex, OP_SELLLIMIT);
                        }//if (TypeOfPendingTrade == Stop_and_Limit_orders)
                        
                           
                     }//if (SendPendingTrades)

                     if (UseGridTrading && (SendImmediateMarketTrade || SendPendingTrades))
                        if (result)
                        {
                           if (TypeOfGrid == Stop || TypeOfGrid == Both)
                           {
                              SendSellGrid(symbol, OP_SELLSTOP, bid, Lot, GridSize );
                           }//if (TypeOfGrid == OP_SELLSTOP || TypeOfGrid == Both)
                           
                           if (TypeOfGrid == Limit || TypeOfGrid == Both)
                           {
                              SendSellGrid(symbol, OP_SELLLIMIT, bid, Lot, GridSize );
                           }//if (TypeOfGrid == OP_BUYSTOP || TypeOfGrid == Both)
                           
                        }//if (result)
                     
                  }//if (SellSignal)
                  
                     
                  //This takes care of grid trading only.
                  if (!SendImmediateMarketTrade && !SendPendingTrades)
                     if (UseGridTrading)
                     {
                        if (BuySignal)
                        {
                           if (TypeOfGrid == Stop || TypeOfGrid == Both)
                           {
                              SendBuyGrid(symbol, OP_BUYSTOP, ask, Lot, GridSize );
                           }//if (TypeOfGrid == Stop || TypeOfGrid == Both)
                                 
                           if (TypeOfGrid == Limit || TypeOfGrid == Both)
                           {
                              SendBuyGrid(symbol, OP_BUYLIMIT, ask, Lot, GridSize );
                           }//if (TypeOfGrid == Limit || TypeOfGrid == Both)
                           
                        }//if (BuySignal)
                        
                        if (SellSignal)
                        {  
                           if (TypeOfGrid == Stop || TypeOfGrid == Both)
                           {
                              SendSellGrid(symbol, OP_SELLSTOP, bid, Lot, GridSize );
                           }//if (TypeOfGrid == OP_SELLSTOP || TypeOfGrid == Both)
                           
                           if (TypeOfGrid == Limit || TypeOfGrid == Both)
                           {
                              SendSellGrid(symbol, OP_SELLLIMIT, bid, Lot, GridSize );
                           }//if (TypeOfGrid == OP_BUYSTOP || TypeOfGrid == Both)
                        }//if (SellSignal)
                        
                     }//if (UseGridTrading)
                       
                     
               }//if (BuySignal || SellSignal)
               
            }//if (OpenTrades < MaxTradesAllowed)
            
         }//if (TimeCurrent() >= TimeToStartTrading[PairIndex])
      }//if (!StopTrading)
     

}//End void CanWeSendTrades(string symbol, int signal)

Thanks for your persistence c1borg. I cannot test every permutation available to Desky, or consider every moment of personal lunacy. I rely on the likes of you to point them out.