Code: Select all

/*
    Count open market and pending orders
*/
int OrdersTotal_()
{
    int orderCount=0;
    
    #ifdef __MQL4__
    // Pending and market orders are held in the same pool
    orderCount = OrdersTotal();
    #endif

    #ifdef __MQL5__
    // Pending and market orders are held in different pools
    orderCount = PositionsTotal() + OrdersTotal();
    #endif

    return orderCount;
}

Code: Select all

/*
    TestScript.mq4
    
    Author: Thunderbolt4x@gmail.com
	
	Description
	==============
    MQ4 stub to compile the script for the Empty4 platform
*/

#property copyright     ""
#property description   ""
#property version       ""
#property strict

// Main code file
#include "TestScript.mqh"

Code: Select all

/*
    TestScript.mq5
    
    Author: Thunderbolt4x@gmail.com
	
	Description
	==============
    MQ5 stub to compile the script for the MT5 platform
*/

#property copyright     ""
#property description   ""
#property version       ""
#property strict        // Not needed for MT5 but the compiler will ignore it

// Main code file
#include "TestScript.mqh"

Code: Select all

/*
    TestScript.mqh
    
    Author: Thunderbolt4x@gmail.com
	
	Description
	==============
    Main code file for the initial example     
*/

void OnStart()
{
    string text = "";

    #ifdef __MQL4__
    text = "Empty4";
    #endif

    #ifdef __MQL5__
    text = "MT5";
    #endif

    Alert("This is a test example script using "+text);
}   

Code: Select all

/*
    Send pending and market orders
*/
int OrderSend_(string symbol, ENUM_ORDER_TYPE cmd, double volume, double price, ulong slippage, double stoploss, double takeprofit, string comment=NULL, int magic=0, datetime expiration=0, color arrow_colour=clrNONE)
{
    int ticket = -1;
    
    #ifdef __MQL4__
    // Nothing needs changing for MQL4
    ticket = OrderSend(symbol, cmd, volume, price, (int)slippage, stoploss, takeprofit, comment, magic, expiration, arrow_colour);
    #endif

    #ifdef __MQL5__
    // We need to create structures to send input properties to the server and also to return result values from the server.    
    MqlTradeRequest request={};
    MqlTradeResult  result={};
      
    // This is what type of order we want to place. DEAL = Market Order and PENDING = Pending order
    ENUM_TRADE_REQUEST_ACTIONS action;
    
    if(cmd <= ORDER_TYPE_SELL)
        action = TRADE_ACTION_DEAL;     // The equivalent of the Empty4 market order 
    else
        action = TRADE_ACTION_PENDING;  // The equivalent of the Empty4 pending order 

    // Add the properties to the sending structure
    request.action          = action;                        
    request.symbol          = symbol;                              
    request.volume          = volume;                                   
    request.type            = cmd;                        
    request.price           = price; 
    request.deviation       = slippage;                                     
    request.magic           = magic;                          
    request.sl              = stoploss;                    
    request.tp              = takeprofit;
    request.type_filling    = ORDER_FILLING_IOC; 
    request.comment         = comment;
    
    if(OrderSend(request, result))
        // Retieve the ticket number from the result structure. The ticket number is actually a long type so to avoid a 
        // compiler warning we explicitly convert it to an int
        ticket = (int)result.order;
    else
        // retcode adds a little more information if there is an error so we might as well report it
        Print("OrderSend error: retcode_external = "+IntegerToString(result.retcode_external)+"   retcode = "+IntegerToString(result.retcode));
    
    #endif

    return ticket;
}

Code: Select all

    
    double bid      = SymbolInfoDouble(_Symbol,SYMBOL_BID);
    double ask      = SymbolInfoDouble(_Symbol,SYMBOL_ASK);
    // SymbolInfoInteger() actually returns a long but will will it return an int so that the compiler doesn't give a warning
    int digits      = (int)SymbolInfoInteger(_Symbol, SYMBOL_DIGITS);  
    double point    = SymbolInfoDouble(_Symbol, SYMBOL_POINT); 

Code: Select all

/*
    Return the name of the EA, Indicator or Script
*/
string WindowExpertName_()
{
    return MQLInfoString(MQL_PROGRAM_NAME);
}