Last OpenPrice of Buy and Sell Orders

[deejoy]

Hi,

i need the last OpenPrice of a Sell Order and of a Buy Order. I try it with this function but i get only the Price of the last open Order.

Code: Select all

double fk_getLastOpenOrderPrice(double d_OrderOpenPrice)
{

double dOpenBuyPrice  ;
double dOpenSellPrice ;
int iAnzOrders = OrdersTotal();

if(OrderSelect(iAnzOrders,SELECT_BY_TICKET)==true){
       
if ((OrderType() == OP_BUY) && (OrderSymbol() == sSymbol))
       {
       
       dOpenBuyPrice = OrderOpenPrice();
       }
       
if ((OrderType() == OP_SELL) && (OrderSymbol() == sSymbol))
       {
       
       dOpenSellPrice = OrderOpenPrice();
       }
  }    
       
if (d_OrderOpenPrice ==1) return(dOpenBuyPrice);
if (d_OrderOpenPrice ==2) return(dOpenSellPrice);
 return(0);

How get i both Openprice ?

[milanese]

this two functions should do what you want..

Code: Select all

double LastOpenBuyTradePrice(string strSymbol, int nMagic)
{
	double priceLastOpenOrder=0;
	datetime opendate=0;
	for (int i=OrdersTotal()-1 ; i>=0 ; i--)
	{
		if (!OrderSelect(i,SELECT_BY_POS)) continue;
		if (OrderType() != OP_BUY) continue;
		if (OrderMagicNumber() == nMagic)
		if (OrderSymbol() == strSymbol)
		if (OrderOpenTime()>=opendate)
		{
			priceLastOpenOrder=OrderOpenPrice();
			opendate=OrderOpenTime();
		}
	}
	return(priceLastOpenOrder);
}
double LastOpenSellTradePrice(string strSymbol, int nMagic)
{
	double priceLastOpenOrder=0;
	datetime opendate=0;
	for (int i=OrdersTotal()-1 ; i>=0 ; i--)
	{
		if (!OrderSelect(i,SELECT_BY_POS)) continue;
		if (OrderType() != OP_SELL) continue;
		if (OrderMagicNumber() == nMagic)
		if (OrderSymbol() == strSymbol)
		if (OrderOpenTime()>=opendate)
		{
			priceLastOpenOrder=OrderOpenPrice();
			opendate=OrderOpenTime();
		}
	}
	return(priceLastOpenOrder);
}

Cheers

Tommaso

[deejoy]

thx
works perfect